class slider

  var id, title, value, oldvalue, min, max, action, globalname, started

  # Not needed for the main page already having JavaScript code doing the same
  # static sliderjs = "<script>function la(p){x=new XMLHttpRequest();x.open('GET','.?m=1'+(p||''),true);x.send();}</script>"

  def init(id, action)
    self.id = id ? id : classname(self)
    self.action = action ? action : /value->print(f'Update {self.id} {self.value}')
    self.globalname = 'slider_instance_' + self.id
    self.title = ''
  end

  def start()
    if self.started return end
    if global.member(self.globalname) global.member(self.globalname).stop() end
    tasmota.add_driver(self)
    global.setmember(self.globalname, self)
    self.started = true
    if self.max   == nil self.setrange(0,100) end
    if self.value == nil self.setvalue(self.max/2) end
    return self
  end

  def stop()
    self.started = false
    tasmota.remove_driver(self)
    global.setmember(self.globalname, nil)
    return self
  end

  def web_sensor()
    import webserver
    if webserver.has_arg(self.id)
      self.setvalue(int(webserver.arg(self.id)))
    elif self.value && self.value != self.oldvalue
      self.oldvalue = self.value
      tasmota.web_send(self.DOMupdate(self.id, self.value))
    end
  end

  def DOMupdate(id, value)
    # This trick allows DOM updates, while <script> tags would be blocked for security reasons
    return f"<img src='data:x,' style='display:none' onerror=\"let obj=eb('{id}');if (obj) obj.{value=};this.remove();\">"
  end

  def settitle(title)    self.title = title  return self end
  def setrange(min, max) self.min = min self.max = max  return self end
  def setvalue(newvalue)
    self.start()
    self.value = newvalue
    var f = self.action
    tasmota.defer(/->f(self.id, self.value))
    return self
  end

  def web_add_main_button()
    import webserver
    webserver.content_send(f'{self.title}<input type="range" class="slider" id="{self.id}" min={self.min} max={self.max} value={self.value} onchange=la("&{self.id}="+value)>')
  end

end

var pwm1duty = slider('pwm1duty',
  def (id, value)
    print(id, value)
    import gpio
    gpio.set_pwm(gpio.pin(gpio.PWM1, 5), value)   # PWM6
  end)
  .setrange(0,1023).setvalue(512).settitle('PWM6')

#-  Other examples:

var test = slider('test').start()   # 0..100 and prints values

var dacmv = slider('dacmv',
  def (id, millivolt)
    print(id, millivolt)
    gpio.pin_mode(25, gpio.DAC)     # DAC of "classic" ESP32 is gpio 25-26, or 17-18 for ESP32-S2
    gpio.dac_voltage(25, millivolt)
  end)
  .setrange(0,3300).setvalue(0)

var pwm1freq = slider('pwm1freq',
  def (id, value)
    print(id, value)
    import gpio
    gpio.set_pwm_freq(gpio.pin(gpio.PWM1, 5), value)   # PWM6
  end)
  .setrange(0,1023).setvalue(440)

var pins = []
var sliders = []
for idx : 0..7
  pins.push(gpio.pin(gpio.PWM1, idx))
  if pins[idx] < 0 break end
  var title = f'pwm{idx+1}-{pins[idx]}'
  sliders.push(slider(title, /id,value -> gpio.set_pwm(pins[idx], value)).settitle(title).setvalue(0))
end
tasmota.set_timer(600000, def () for oneslider : sliders oneslider.stop() end end)

-#